home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Belgian Amiga Club - ADF Collection
/
BS1 part 23.zip
/
BS1 part 23
/
Prof page II util.adf
/
HD
/
Install-Proc
< prev
next >
Wrap
AmigaDOS Script File
|
1990-12-17
|
7KB
|
214 lines
.KEY dest
.BRA {
.KET }
;
; Do the PPage installation:
;
; Inputs:
; dest Where stuff should go.
IF NOT EXISTS "PPageInstDest:PPage"
ECHO " Creating Directory {dest}PPage ..."
MAKEDIR "PPageInstDest:PPage"
COPY PPageInstUtil:HD.info "PPageInstDest:PPage.info"
ENDIF
;
; Install the program itself.
;
INSTUTIL ask -dy "Install the Professional Page program [Y/N]? Y"
IF NOT WARN
EXECUTE RAM:PPageInstall/DiskMount "Program Disk" PPage: PPageInstPgm:
ECHO "*N Copying Professional Page program ...*N"
COPY PPageInstPgm:PPage "PPageInstDest:PPage/PPage"
COPY PPageInstPgm:PPage.info "PPageInstDest:PPage/PPage.info"
INSTUTIL reseticon "PPageInstDest:PPage/PPage"
COPY PPageInstPgm:PANTONE_data.bin "PPageInstDest:PPage"
;
; these libraries are necessary for PPage, make sure that they are there:
;
IF NOT EXISTS LIBS:mathtrans.library
ECHO "*N Copying mathtrans.library"
COPY PPageInstPgm:libs/mathtrans.library LIBS:
ENDIF
IF NOT EXISTS LIBS:diskfont.library
ECHO "*N Copying diskfont.library"
COPY PPageInstPgm:libs/diskfont.library LIBS:
ENDIF
IF NOT EXISTS "PPageInstDest:PPage/Data"
MAKEDIR "PPageInstDest:PPage/Data"
ENDIF
COPY PPageInstUtil:Data "PPageInstDest:PPage/Data" ALL QUIET
COPY PPageInstUtil:PPage_Any_Font "PPageInstDest:PPage"
ENDIF
ECHO "*N"
INSTUTIL ask -dy "Copy Tutorial Files to {dest}PPage [Y/N]? Y"
IF NOT warn
IF NOT EXISTS "PPageInstDest:PPage/NewsLetter"
MAKEDIR "PPageInstDest:PPage/NewsLetter"
ENDIF
COPY PPageInstUtil:NewsLetter "PPageInstDest:PPage/NewsLetter" ALL QUIET
COPY PPageInstUtil:NewsLetter.info "PPageInstDest:PPage"
INSTUTIL reseticon "PPageInstDest:PPage/NewsLetter"
ENDIF ; copy Tutorial files
ECHO "*N"
INSTUTIL ask -dy "Copy PPage Bitmap fonts to FONTS: directory [Y/N]? Y"
IF NOT warn
FAILAT 21
ECHO "*N Copying Bitmap fonts to FONTS:"
COPY PPageInstUtil:fonts FONTS: ALL QUIET
IF error
ECHO "*N Not enough room on the FONTS: directory*N"
ENDIF
FAILAT 10
ELSE
INSTUTIL ask -dy "Copy PPage Bitmap fonts to {dest}PPage/Fonts [Y/N]? Y"
IF NOT warn
ECHO "*N Copying Bitmap fonts to {dest}PPage/Fonts:"
IF NOT EXISTS "PPageInstDest:PPage/Fonts"
MAKEDIR "PPageInstDest:PPage/Fonts"
ENDIF
COPY PPageInstUtil:fonts "PPageInstDest:PPage/Fonts" ALL QUIET
;
; Make a couple of IconX files to switch between PPage and normal fonts.
;
CD RAM:PPageInstall
ECHO >SelPP.1 "Echo *"Selecting Professional Page fonts: *" NOLINE"
ECHO >SelPP.2 "Assign FONTS: *"{dest}PPage/Fonts*""
ECHO >Sel.Done "Echo *"Done.*""
JOIN SelPP.1 SelPP.2 Sel.Done AS "PPageInstDest:PPage/PPageFonts"
COPY PPageInstUtil:HD/Icons/PPageFonts.info "PPageInstDest:PPage/PPageFonts.info"
ECHO >SelAm.1 "Echo *"Selecting Amiga fonts: *" NOLINE"
ECHO >SelAm.2a "Assign FONTS: " NOLINE
CD FONTS:
CD >RAM:PPageInstall/SelAm.2b
CD RAM:PPageInstall
JOIN SelAm.1 SelAm.2a SelAm.2b Sel.Done AS "PPageInstDest:PPage/AmigaFonts"
COPY PPageInstUtil:HD/Icons/AmigaFonts.info "PPageInstDest:PPage/AmigaFonts.info"
ENDIF
ENDIF ; copy FONTS
ECHO "*N"
INSTUTIL ask -dy "Copy Article Editor to {dest}PPage [Y/N]? Y"
IF NOT warn
; Copy the editor
IF NOT EXISTS "PPageInstDest:PPage/CGFonts"
MAKEDIR "PPageInstDest:PPage/CGFonts"
COPY PPageInstUtil:HD.info PPageInstDest:PPage/CGFonts.info
ENDIF
EXECUTE RAM:PPageInstall/DiskMount "Compugraphic Fonts Disk" CGFonts: PPageInstCG:
ECHO "*N"
INSTUTIL -ePPageVersion1 version PPageInstDest:CGFonts/AE
INSTUTIL -ePPageVersion2 version PPageInstCG:AE
IF NOT val $PPageVersion1 gt $PPageVersion2
ECHO "Copying Article Editor"
COPY PPageInstCG:AE "PPageInstDest:PPage/CGFonts/AE" QUIET
COPY PPageInstCG:AE.info "PPageInstDest:PPage/CGFonts/AE.info" QUIET
ENDIF
INSTUTIL -ePPageResult1 version PPageInstDest:CGFonts/TransSpell
INSTUTIL -ePPageResult2 version PPageInstCG:TransSpell
IF NOT val $PPageVersion1 gt $PPageVersion2
ECHO "Copying Spell Checker"
COPY PPageInstCG:TransSpell "PPageInstDest:PPage/CGFonts/TransSpell" QUIET
COPY PPageInstCG:TransSpell.info "PPageInstDest:PPage/CGFonts/TransSpell.info" QUIET
ENDIF
INSTUTIL -ePPageResult1 version PPageInstDest:CGFonts/pfsf6b90k
INSTUTIL -ePPageResult2 version PPageInstCG:pfsf6b90k
IF NOT val $PPageVersion1 gt $PPageVersion2
ECHO "Copying Dictionary"
COPY PPageInstCG:pfsf6b90k "PPageInstDest:PPage/CGFonts" QUIET
ENDIF
ENDIF
ECHO "*N"
INSTUTIL ask -dy "Copy Compugraphic Fonts to {dest}PPage/CGFonts [Y/N]? Y"
IF NOT warn
; Copy the CGFonts stuff
EXECUTE RAM:PPageInstall/DiskMount "Compugraphic Fonts Disk" CGFonts: PPageInstCG:
ECHO "*N Copying Compugraphic Fonts ..."
IF NOT EXISTS "PPageInstDest:PPage/CGFonts"
MAKEDIR "PPageInstDest:PPage/CGFonts"
COPY PPageInstUtil:HD.info PPageInstDest:PPage/CGFonts.info
ENDIF
IF NOT EXISTS "PPageInstDest:PPage/CGFonts/CGCache"
MAKEDIR "PPageInstDest:PPage/CGFonts/CGCache"
ENDIF
COPY PPageInstCG:Times#? "PPageInstDest:PPage/CGFonts" QUIET
COPY PPageInstCG:Triumvirate#? "PPageInstDest:PPage/CGFonts" QUIET
INSTUTIL -ePPageResult1 version PPageInstDest:CGFonts/CGT
INSTUTIL -ePPageResult2 version PPageInstCG:CGT
IF NOT val $PPageResult1 gt $PPageResult2
COPY PPageInstCG:CGT "PPageInstDest:PPage/CGFonts/CGT" QUIET
ENDIF
COPY PPageInstCG:psfont.alias "PPageInstDest:PPage/CGFonts/psfont.alias" QUIET
COPY PPageInstCG:CacheEdit "PPageInstDest:PPage/CacheEdit" QUIET
COPY PPageInstCG:CacheEdit.info "PPageInstDest:PPage/CacheEdit.info" QUIET
INSTUTIL reseticon "PPageInstDest:PPage/CacheEdit"
ENDIF ; copy CG Fonts
ENDSKIP
;
; The Assign commands for startup-sequence
;
CD RAM:PPageInstall
ECHO >AsnPPage "ASSIGN PPage: *"{dest}PPage*""
ECHO >AsnUtil "ASSIGN PPageUtil: *"{dest}PPage*""
IF EXISTS "PPageInstDest:PPage/CGFonts"
ECHO >AsnCFonts "ASSIGN CGFonts: *"{dest}PPage/CGFonts*""
ELSE
COPY NIL: to AsnCFonts
ENDIF
IF EXISTS "PPageInstDest:PPage/CGFonts/CGCache"
ECHO >AsnCCache "ASSIGN CGCache: *"{dest}PPage/CGFonts/CGCache*""
ELSE
COPY NIL: to AsnCCache
ENDIF
ECHO >AsnPMS "ASSIGN PMS: *"{dest}PPage*""
VERSION >nil: graphics.library 36
IF NOT WARN
IF NOT EXISTS SYS:WBStartup
MAKEDIR SYS:WBStartup
ENDIF
JOIN AsnPPage AsnUtil AsnCFonts AsnCCache AsnPMS as SYS:WBStartup/PPageStartup
COPY PPageInstUtil:HD/icons/PPageStartup.info SYS:WBStartup
INSTUTIL reseticon SYS:WBStartup/PPageStartup
ELSE
JOIN AsnPPage AsnUtil AsnCFonts AsnCCache AsnPMS as S:PPageStartup
ENDIF